ERP – Função AbrirTelaSistema - Como utilizar a Função AbrirTelaSistema para abrir a tela de Quadro Comparativo de Propostas de Cotações
Dúvida
Como utilizar a Função AbrirTelaSistema para abrir a tela NF410QCP_SCCP - Suprimentos / Gestão de Compras / Cotação de Preço / Quadro comparativo de propostas (Quadro Comparativo de Propostas de Cotações)?
Solução
Para utilizar a função AbrirTelaSistema para abrir a tela NF410QCP_SCCP - Suprimentos / Gestão de Compras / Cotação de Preço / Quadro comparativo de propostas (Quadro Comparativo de Propostas de Cotações), defina uma regra onde sejam informadas as 2 posições possíveis de parâmetros para a função AbrirTelaSistema para esta tela. Os parâmetros possíveis para essa tela são:
- NumSol - alfa - Número da Solicitação de Compra;
- CodFam - alfa - Código da Família;
- CodPro - alfa - Código do Produto;
- CodDer - alfa - Código da Derivação;
- CodSer - alfa - Código do Serviço;
- NumCot - alfa - Número da Cotação;
- NumPct - alfa - Número do Processo de Cotação;
- Selecão - alfa - Botão "Selecionar" da Tela. Opções: 0 (Produto), 1 (Serviço), 2 (Todos).
Importante
Os parâmetros deverão obedecer a ordem/tipo conforme descrito acima. No entanto, eles não são obrigatórios.
Segue um exemplo de regra abaixo de envio dos parâmetros para abertura da tela.
No exemplo está sendo enviado valor para todos os campos da tela, no entanto, é apenas um exemplo, pois não é obrigatório o envio de todos os parâmetros.
Definir Alfa VParametros;
Definir Numero nRet;
@ Número da Solicitação de Compra @
Definir Numero nNumSol;
@ Código da Família @
Definir Alfa aCodFam;
@ Código do Produto @
Definir Alfa aCodPro;
@ Código da Derivação @
Definir Alfa aCodDer;
@ Código do Serviço @
Definir Alfa aCodSer;
@ Número da Cotação @
Definir Numero nNumCot;
@ Número do Processo de Cotação @
Definir Numero nNumPct;
@ Botão "Selecionar" da Tela. Opções => 0Produto, 1Serviço, 2Todos @
Definir Numero nSelecao;
@ Variáveis Alfa para o envio de parâmetros na função, pois todos tem que ser Alfa@
Definir Alfa aNumSol;
Definir Alfa aNumCot;
Definir Alfa aNumPct;
Definir Alfa aSelecao;
@ Atribuição dos valores @
nNumSol = 12782;
aCodFam = "\"10\"";
aCodPro = "\"0000001\"";
aCodDer = "\"0001\"";
aCodSer = "\"SER001\"";
nNumCot = 21526;
nNumPct = 37;
nSelecao = 2;
@ Conversão dos valores de Numero para Alfa @
IntParaAlfa(nNumSol,aNumSol);
IntParaAlfa(nNumCot,aNumCot);
IntParaAlfa(nNumPct,aNumPct);
IntParaAlfa(nSelecao,aSelecao);
/* Por padrão variáveis numéricas recebem o valor 0 se não for passado valor
então é necessário limpar a variável Alfa caso não seja enviado valor para
os parâmetros numéricos, para que não seja enviado o 0 para os filtros da tela
*/
Se (nNumSol = 0)
aNumSol = "";
Se (nNumCot = 0)
aNumCot = "";
Se (nNumPct = 0)
aNumPct = "";
Se (nSelecao = 0)
aSelecao = "";
/* A ordem de passagem dos parâmetros deve ser seguida conforme segue no
exemplo abaixo. Se um dos campos não receber valor, ele não será enviado
para a tela quando for aberta. Exemplo, se não for informado o aCodFam,
aCodPro e aCodDer, eles vão ser enviados em branco para a tela.
*/
VParametros = aNumSol + ";" +
aCodFam + ";" +
aCodPro + ";" +
aCodDer + ";" +
aCodSer + ";" +
aNumCot + ";" +
aNumPct + ";" +
aSelecao + ";";
AbrirTelaSistema("F410QCP",VParametros,nRet);
Observação
Para maiores informações sobre a função AbrirTelaSistema acesse o artigo TECNOLOGIA - Função AbrirTelaSistema - Onde é possível encontrar informações diversas sobre processo a Função AbrirTelaSistema (índice).